1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

Sub DualPrint()
    Dim answer As Integer
    Dim nPages As Integer
    nPages = Word.ActiveDocument.range.Information(wdNumberOfPagesInDocument)
    answer = MsgBox("当前文档共 " & nPages & " 页" & vbCrLf & "当前打印机为 " & ActivePrinter & vbCrLf & "是否使用此打印机进行打印？", vbQuestion + vbYesNo + vbDefaultButton2, "确认打印机")
    If answer = vbNo Then
        Exit Sub
    End If
        
    Dim range As Integer
    Dim pages As String
    If nPages Mod 2 = 0 Then
        '偶数页的话打印全部页
        range = wdPrintAllDocument
        pages = ""
    Else
        '奇数页的话不打印最后一页
        range = wdPrintRangeOfPages
        pages = "1-" & (nPages - 1)
    End If
    
    '正序打印奇数页
    Options.PrintReverse = False
    Application.PrintOut FileName:="", range:=range, Item:= _
        wdPrintDocumentWithMarkup, Copies:=1, pages:=pages, PageType:= _
        wdPrintOddPagesOnly, Collate:=True, Background:=False, PrintToFile:=False, _
         PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0
        
    answer = MsgBox("请将纸张旋转180放入托盘，注意不要正反翻转！" & vbCrLf & "页码在后，标题在前，空白面朝上，送入纸盘" & vbCrLf & "（纸面上如果有“甲”字旋转后应该看到“由”字）", vbOKCancel, "提示")
    If answer = vbCancel Then
        Exit Sub
    End If
    
    '逆序打印偶数页
    Options.PrintReverse = True
    Application.PrintOut FileName:="", range:=range, Item:= _
        wdPrintDocumentWithMarkup, Copies:=1, pages:=pages, PageType:= _
        wdPrintEvenPagesOnly, Collate:=True, Background:=False, PrintToFile:=False, _
         PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0
    
    '奇数页的话打印最后一页
    '最后一页不可以先打印，否则双面顺序会错乱
    If nPages Mod 2 <> 0 Then
        Application.PrintOut FileName:="", range:=wdPrintRangeOfPages, Item:= _
            wdPrintDocumentWithMarkup, Copies:=1, pages:=Str(nPages), PageType:= _
            wdPrintOddPagesOnly, Collate:=True, Background:=False, PrintToFile:=False, _
             PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
            PrintZoomPaperHeight:=0
    End If

    '逆序打印偶数页
    Options.PrintReverse = True
End Sub